remove meson

meson.build

@@ -1,33 +0,0 @@
-project('kima2', 'cpp', default_options : ['cpp_std=c++20'], version : '1.8.0')
-
-conf_data = configuration_data()
-conf_data.set('PROJECT_VERSION', '"' + meson.project_version() + '"')
-configure_file(output : 'config.h',
-               configuration : conf_data)
-configuration_inc = include_directories('.')
-               
-#csv = cmake.subproject('csv-parser')
-#csv_lib = csv.dependency('csv')
-
-nlohmann_lib = dependency('nlohmann_json', version : '>=3.5.0', required : false)
-
-if not nlohmann_lib.found()
-  nlohmann_inc = include_directories('subprojects/nlohmann_json/single_include')
-  nlohmann_lib = declare_dependency(include_directories : nlohmann_inc)
-endif
-
-csv_inc = include_directories('subprojects/csv-parser/single_include')
-csv_dep = declare_dependency(include_directories : csv_inc)
-
-singleapp_proj = subproject('singleapplication')
-singleapp_lib = singleapp_proj.get_variable('singleapp_lib')
-singleapp_dep = singleapp_proj.get_variable('singleapp_dep')
-
-subdir('src')
-
-if build_machine.system() == 'linux'
-  install_data('misc/kima2.svg', install_dir : get_option('datadir') / 'icons/hicolor/scalable/apps')
-  install_data('misc/kima2.desktop', install_dir : get_option('datadir') / 'applications')
-  install_data('manual/Benutzerhandbuch.pdf', install_dir : get_option('datadir') / 'kima2')
-endif
-

src/core/meson.build

@@ -1,13 +0,0 @@
-boost = dependency('boost', modules: ['date_time'], static: true)
-xlnt = dependency('xlnt')
-sqlite = dependency('sqlite3')
-
-src = ['database.cpp', 'entity.cpp', 'entityint.cpp', 'entityuuid.cpp',
-       'seller.cpp', 'article.cpp', 'sale.cpp', 'marketplace.cpp',
-       'excelreader.cpp', 'csvreader.cpp', 'jsonutil.cpp', 'utils.cpp']
-
-core_inc = include_directories('..')
-
-core_lib = static_library('core', src, dependencies: [boost, xlnt, sqlite, nlohmann_lib, csv_dep])
-
-core_dep = declare_dependency(link_with: core_lib, include_directories : core_inc)

src/gui/meson.build

@@ -1,23 +0,0 @@
-qt5 = import('qt5')
-qt5_dep = dependency('qt5', modules: ['Core', 'Gui', 'PrintSupport', 'Network'])
-
-thread_dep = dependency('threads')
-
-
-src = ['kima2.cpp', 'mainwindow.cpp',  'sellerdialog.cpp', 'sellermodel.cpp', 
-       'pricedialog.cpp', 'basketmodel.cpp', 'salemodel.cpp', 'reportdialog.cpp',
-       'reportmodel.cpp', 'settingsdialog.cpp']
-    
-ui = ['mainwindow.ui', 'sellerdialog.ui', 'pricedialog.ui', 'reportdialog.ui', 'settingsdialog.ui']
-
-processed = qt5.preprocess(moc_headers : ['basketmodel.h', 'mainwindow.h', 'pricedialog.h',
-                                          'reportdialog.h', 'sellerdialog.h', 'settingsdialog.h',
-                                          'sellermodel.h', 'salemodel.h'],
-                           ui_files : ui,
-                           qresources : '../../kima2.qrc',
-                           dependencies: qt5_dep)
-                           
-kima2 = executable('kima2', sources : [src, processed], 
-                   dependencies : [qt5_dep, singleapp_dep, core_dep, printer_dep, thread_dep],
-                   include_directories : [configuration_inc],
-		   install : true)

src/meson.build

@@ -1,3 +0,0 @@
-subdir('core')
-subdir('printer')
-subdir('gui')

src/printer/meson.build

@@ -1,9 +0,0 @@
-libusb = dependency('libusb-1.0')
-
-src = ['posprinter.cpp', 'utils.cpp']
-
-printer_inc = include_directories('..')
-
-printer_lib = static_library('printer', src, dependencies: [libusb, core_dep])
-
-printer_dep = declare_dependency(link_with : printer_lib, include_directories : printer_inc)