project('kima2', 'cpp', default_options : ['cpp_std=c++17'], version : '1.6.0')

conf_data = configuration_data()
conf_data.set('PROJECT_VERSION', '"' + meson.project_version() + '"')
configure_file(output : 'config.h',
               configuration : conf_data)
configuration_inc = include_directories('.')
               
cmake = import('cmake')

#csv = cmake.subproject('csv-parser')
#csv_lib = csv.dependency('csv')

nlohmann_lib = dependency('nlohmann_json', version : '>=3.5.0', required : false)

if not nlohmann_lib.found()
  nlohmann = cmake.subproject('nlohmann_json', 
                            cmake_options : ['-DJSON_BuildTests=OFF', '-DCMAKE_BUILD_TYPE=Release'])
  nlohmann_lib = nlohmann.dependency('nlohmann_json')
endif

singleapp_proj = subproject('singleapplication')
singleapp_lib = singleapp_proj.get_variable('singleapp_lib')
singleapp_dep = singleapp_proj.get_variable('singleapp_dep')

subdir('src')

if build_machine.system() == 'linux'
  install_data('misc/kima2.svg', install_dir : get_option('datadir') / 'icons/hicolor/scalable/apps')
  install_data('misc/kima2.desktop', install_dir : get_option('datadir') / 'applications')
  install_data('manual/Benutzerhandbuch.pdf', install_dir : get_option('datadir') / 'kima2')
endif